package {
	import fl.controls.listClasses.ICellRenderer;
	import fl.controls.listClasses.ImageCell;
	import fl.controls.TileList;
	import flash.text.*;
	
	public class Thumb extends ImageCell implements ICellRenderer {  
		private var desc:TextField;
		private var textStyle:TextFormat;
		
    	public function Thumb() {
			super();
			
			loader.scaleContent = false;
			useHandCursor = true;
			
			// set skins
			setStyle("upSkin", ThumbCellBg);
			setStyle("downSkin", ThumbCellBg);
     	    setStyle("overSkin", ThumbCellBgOver);
			
     	    setStyle("selectedUpSkin", ThumbCellBgSelected);
    		setStyle("selectedDownSkin", ThumbCellBgSelected);
    	    setStyle("selectedOverSkin", ThumbCellBgSelected);
			
			// Create and format desc
			desc = new TextField();
			desc.autoSize = TextFieldAutoSize.LEFT;
			desc.x = 65;
			desc.width = 133;
			desc.multiline = true;
			desc.wordWrap = true;
			addChild(desc);
			
			textStyle = new TextFormat();
			textStyle.font = "Verdana";
			textStyle.color = 0xFFFFFF;
			textStyle.size = 13;
    	}
	
		override protected function drawLayout():void {
			// Position cell elements; tweak these for your thumbs if needed
			var imagePadding:Number = getStyleValue("imagePadding") as Number;
			loader.move(11, 5);
			
			var w:Number = width-(imagePadding*2);
			var h:Number = height-imagePadding*2;
			
			if (loader.width != w && loader.height != h) {
				loader.setSize(w,h);
			}
			
			loader.drawNow();

			desc.text = data.label;
			desc.setTextFormat(textStyle);
			
			background.width = width+5;
			background.height = height+1;
			textField.visible = false;
		}
	}
}